HandsOnChain

発行体の役割を分ける

作るもの

このレッスンを終えると、円トークンが発行と本人確認と停止の3つの役割を持ち、デプロイした発行体のアカウントが最初は全ての役割を持ちます。
役割を持たない人が役割を付与しようとすると、コントラクトが拒みます。
節1でデプロイしたアカウントに持たせた100万円分は、ここで外します。
これからは、発行の役割を持つアカウントが入金に応じて発行した分だけが、円トークンになります。

背景

銀行は、1人の担当者が入金の確認から送金の実行までを全て行える体制を避けます。
入力する人と承認する人を分ける「職務の分離」と呼ばれる考え方で、1人の誤りや不正がそのまま事故になるのを防ぎます。

円トークンにも同じ考え方を使えます。
発行する人、本人確認の結果を書く人、緊急時に全体を止める人を分けておきます。
OpenZeppelin ContractsのAccessControlは、役割ごとに関数を呼べるアカウントを分ける仕組みです。

役割 名前 受け持つ操作
管理 DEFAULT_ADMIN_ROLE 他の役割を付与する、取り消す
発行 ISSUER_ROLE 入金に応じて発行する
本人確認 COMPLIANCE_ROLE 許可リストと凍結を書く
停止 PAUSER_ROLE 全体を一時停止する

このコースでは、ローカルで試しやすいように最初は1つのアカウントに全ての役割を持たせます。
本番の運用では、役割ごとに別のアカウントや、複数人の承認が要るアカウントへ付与し直します。

実装

JpyToken.solにAccessControlを足し、役割の名前とconstructorを書きます。
constructorは、最初に役割を持つアカウントを受け取ります。
デプロイしたアカウントに100万円分を持たせていたconstructorは、このconstructorに置き換えます。

import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import {AccessControl} from "@openzeppelin/contracts/access/AccessControl.sol";

/// @title 円建てステーブルコイン
/// @notice 1トークンを1円として扱うERC-20の円トークン
contract JpyToken is ERC20, AccessControl {
    /// @notice 入金に応じて発行する役割
    bytes32 public constant ISSUER_ROLE = keccak256("ISSUER_ROLE");
    /// @notice 許可リストと凍結を扱う役割
    bytes32 public constant COMPLIANCE_ROLE = keccak256("COMPLIANCE_ROLE");
    /// @notice 全体を一時停止する役割
    bytes32 public constant PAUSER_ROLE = keccak256("PAUSER_ROLE");

    /// @param admin 全ての役割を最初に持つ発行体のアカウント
    constructor(address admin) ERC20("HandsOn JPY", "HJPY") {
        _grantRole(DEFAULT_ADMIN_ROLE, admin);
        _grantRole(ISSUER_ROLE, admin);
        _grantRole(COMPLIANCE_ROLE, admin);
        _grantRole(PAUSER_ROLE, admin);
    }
}
行 意味
keccak256("ISSUER_ROLE") 役割の名前を32バイトの値にする。
AccessControlは役割をこの値で見分ける
_grantRole(役割, アカウント) アカウントに役割を付与する。
constructorの中だけで呼び、付与する権限を確かめずに付与する
constructor(address admin) デプロイする時に発行体のアカウントを受け取る。
_mintを消したので、デプロイした直後の供給量は0になる

テストのsetUpは、発行体のアカウントを作ってconstructorへ渡すように変えます。
makeAddr("issuer")は、名前から決まるアカウントのアドレスを作るFoundryの関数です。
デプロイしたアカウントが100万円分を持つことを確かめていたtest_DeployerHoldsInitialSupplyは消し、役割のテストを2つ足します。

import {Test} from "forge-std/Test.sol";
import {IAccessControl} from "@openzeppelin/contracts/access/IAccessControl.sol";

import {JpyToken} from "../contracts/JpyToken.sol";

contract JpyTokenTest is Test {
    JpyToken internal token;

    address internal issuer = makeAddr("issuer");
    address internal alice = makeAddr("alice");

    function setUp() public {
        token = new JpyToken(issuer);
    }

    // 節1 円トークンの型

    function test_NameSymbolDecimals() public view {
        assertEq(token.name(), "HandsOn JPY");
        assertEq(token.symbol(), "HJPY");
        assertEq(token.decimals(), 18);
    }

    // 節2 発行と償還

    function test_IssuerHoldsAllRoles() public view {
        assertTrue(token.hasRole(token.DEFAULT_ADMIN_ROLE(), issuer));
        assertTrue(token.hasRole(token.ISSUER_ROLE(), issuer));
        assertTrue(token.hasRole(token.COMPLIANCE_ROLE(), issuer));
        assertTrue(token.hasRole(token.PAUSER_ROLE(), issuer));
    }

    function test_RevertWhen_GrantRoleWithoutAdmin() public {
        bytes32 adminRole = token.DEFAULT_ADMIN_ROLE();
        bytes32 issuerRole = token.ISSUER_ROLE();
        vm.expectRevert(
            abi.encodeWithSelector(IAccessControl.AccessControlUnauthorizedAccount.selector, alice, adminRole)
        );
        vm.prank(alice);
        token.grantRole(issuerRole, alice);
    }
}
行 意味
vm.expectRevert(...) 次の呼び出しが、このエラーで拒まれることを求める。
拒まれなければテストが落ちる
vm.prank(alice) 次の呼び出しをaliceが送ったものとして扱う

constructorが発行体のアカウントを受け取るようになったので、Hardhat Ignitionのignition/modules/JpyToken.tsも、デプロイするアカウントを発行体として渡すように変えます。

import { buildModule } from "@nomicfoundation/hardhat-ignition/modules";

// デプロイする人のアカウントを発行体にし、全ての役割を持たせて円トークンをデプロイする
export default buildModule("JpyTokenModule", (m) => {
  const issuer = m.getAccount(0);
  const token = m.contract("JpyToken", [issuer]);
  return { token };
});
行 意味
m.getAccount(0) デプロイに使うアカウントのうち、最初のアカウントを発行体にする。
anvilでは0xf39F…2266のアカウントになる
m.contract("JpyToken", [issuer]) constructorに発行体のアカウントを渡して、JpyTokenをデプロイする

test/deploy.test.tsでは、100万円分の残高を確かめていた行を消し、デプロイしたアカウントが4つの役割を持つことを確かめるテストを足します。

import assert from "node:assert/strict";
import { describe, it } from "node:test";

import { network } from "hardhat";

import JpyTokenModule from "../ignition/modules/JpyToken.js";

describe("JpyTokenModule", async function () {
  const { ignition, viem } = await network.create();

  it("ignition-deploys-token", async function () {
    const { token } = await ignition.deploy(JpyTokenModule);
    assert.equal(await token.read.symbol(), "HJPY");
  });

  it("ignition-grants-issuer-roles", async function () {
    const { token } = await ignition.deploy(JpyTokenModule);
    const [issuer] = await viem.getWalletClients();

    const roles = [
      await token.read.DEFAULT_ADMIN_ROLE(),
      await token.read.ISSUER_ROLE(),
      await token.read.COMPLIANCE_ROLE(),
      await token.read.PAUSER_ROLE(),
    ];
    for (const role of roles) {
      assert.equal(await token.read.hasRole([role, issuer.account.address]), true);
    }
  });
});

token.read.hasRole(...)は、viemでコントラクトの読み取りの関数を呼びます。
issuerはIgnitionがデプロイに使ったアカウントと同じなので、全ての役割がtrueになります。

確かめる

starter/contractsのディレクトリで、FoundryとHardhatのテストを実行します。

forge test
pnpm run build
pnpm run test:hardhat

Foundryの3つのテストが[PASS]になり、Hardhatのテストで2つの行が出れば通っています。

[PASS] test_IssuerHoldsAllRoles()
[PASS] test_NameSymbolDecimals()
[PASS] test_RevertWhen_GrantRoleWithoutAdmin()
  JpyTokenModule
    ✔ ignition-deploys-token
    ✔ ignition-grants-issuer-roles

画面は節1のままです。
pnpm devで開き直すと、発行体の残高は0円になります。
次の2つのレッスンで発行と償還をコントラクトに足し、この節の最後に発行体の画面を作ります。