HandsOnChain

円トークンの型を作る

作るもの

このレッスンを終えると、HandsOn JPYという名前とHJPYという記号を持つERC-20の円トークンができ、名前と記号と桁をFoundryのテストで確かめられます。
円トークンをデプロイしたアカウントは、最初から100万円分を持ちます。
この100万円分は、この節の最後に作る画面で送金を試すためのもので、次の節で入金に応じた発行に置き換えます。

背景

ステーブルコインは、円やドルと同じ価値を保つように作ったトークンです。
日本では2023年6月に施行された改正資金決済法で、法定通貨の額で発行し、同じ額で払い戻すことを約束したステーブルコインが電子決済手段として位置づけられました。
発行できるのは銀行と資金移動業者と信託会社で、いずれも払い戻しの義務を負います。

銀行の預金は、銀行が持つ帳簿の上の数字です。
円トークンは、その帳簿をチェーンの上に置いたものと考えると分かりやすくなります。
Ethereum系のチェーンでは、誰がいくら持っているかを全員が同じ方法で読めるように、ERC-20という規格が残高と送金の関数の形を決めています。

関数 何をするか
balanceOf(アカウント) アカウントの残高を返す
transfer(送り先, 額) 自分の残高から送り先へ送る
totalSupply() 発行した円トークンの合計を返す
decimals() 小数点以下の桁数を返す

円には1円未満の単位がありません。
それでもdecimalsは、ERC-20で広く使われている18桁のままにします。
ウォレットや取引所の多くが、18桁を前提に表示するためです。
画面では1円を1 × 10^18として扱い、表示する時に円へ戻します。

実装

starter/contracts/contracts/JpyToken.solを開き、OpenZeppelin ContractsのERC-20を継承する形に書き換えます。

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";

/// @title 円建てステーブルコイン
/// @notice 1トークンを1円として扱うERC-20の円トークン
contract JpyToken is ERC20 {
    /// @notice デプロイしたアカウントに、画面で送金を試せる100万円分を持たせる
    constructor() ERC20("HandsOn JPY", "HJPY") {
        _mint(msg.sender, 1_000_000 * 10 ** decimals());
    }
}
行 意味
import {ERC20} ... 監査を重ねたOpenZeppelin ContractsのERC-20を読み込む。
残高と送金の処理を自分で書かずに済む
contract JpyToken is ERC20 ERC-20の関数を全て継承する
ERC20("HandsOn JPY", "HJPY") 名前と記号を決める
_mint(msg.sender, ...) デプロイしたアカウント (msg.sender) の残高と供給量を増やす。
10 ** decimals()を掛けて、100万を18桁の単位にする

次にstarter/contracts/test/JpyToken.t.solを新しく作り、Foundryのテストを書きます。

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import {Test} from "forge-std/Test.sol";

import {JpyToken} from "../contracts/JpyToken.sol";

contract JpyTokenTest is Test {
    JpyToken internal token;

    function setUp() public {
        token = new JpyToken();
    }

    // 節1 円トークンの型

    function test_NameSymbolDecimals() public view {
        assertEq(token.name(), "HandsOn JPY");
        assertEq(token.symbol(), "HJPY");
        assertEq(token.decimals(), 18);
    }

    function test_DeployerHoldsInitialSupply() public view {
        assertEq(token.balanceOf(address(this)), 1_000_000 ether);
        assertEq(token.totalSupply(), 1_000_000 ether);
    }
}

setUpは各テストの前に呼ばれ、毎回新しい円トークンを作ります。
test_で始まる関数がテストになります。
assertEqは、2つの値が等しいかを確かめます。

コード 意味
address(this) テストのコントラクト自身のアカウント。
setUpで円トークンをデプロイしたのはこのアカウントなので、100万円分を持つ
1_000_000 ether 1000000 × 10^18のこと。
Solidityのetherは18桁の単位で、円トークンの1円にも同じ桁を使う

確かめる

starter/contractsのディレクトリでテストを実行します。

forge test

次の行が出れば、テストは通っています。

[PASS] test_DeployerHoldsInitialSupply()
[PASS] test_NameSymbolDecimals()
Suite result: ok. 2 passed; 0 failed; 0 skipped

assertEq(token.decimals(), 18)の18を0に変えて実行し、[FAIL]の行が出ることも試しておきます。
テストが誤りを見つけられることを、自分の目で確かめておくためです。